#bas
' strConn : имя сетевого подключения
' bState  : vbTrue - включить, vbFalse - отключить

Function SetConnState (strConn, bState)
  Dim objShell,objCP
  Dim colNetwork,clsConn,clsLANConn,clsVerb
  Dim strNetConn,strEnable,strDisable
  SetConnState=vbFalse

  strNetConn = "Сетевые подключения"
' strNetConn = "Network Connections"

  strEnable = "&Включить"
' strEnable = "En&able"

  strDisable = "&Отключить"
' strDisable = "Disa&ble"
' -----------------------------
  Set objShell = CreateObject("Shell.Application")
  Set objCP = objShell.Namespace(3)

  Set colNetwork = Nothing
  For Each clsConn in objCP.Items
    If clsConn.Name = strNetConn Then
      Set colNetwork = clsConn.getfolder
      Exit For
    End If
  Next

  If colNetwork Is Nothing Then
    WScript.Echo "Network folder not found"
    Exit Function
  End If

  Set clsLANConn = Nothing
  For Each clsConn in colNetwork.Items
    If LCase(clsConn.name) = LCase(strConn) Then
      Set clsLANConn = clsConn
      Exit For
    End If
  Next

  If clsLANConn is Nothing Then
    WScript.Echo "Network Connection not found"
    Exit Function
  End If

  For Each clsVerb in clsLANConn.verbs
    If (bState=vbFalse AND clsVerb.name=strDisable) OR (bState=vbTrue AND clsVerb.name=strEnable) Then 
      clsVerb.DoIt
      WScript.Sleep 1000
      SetConnState=vbTrue
    End If
  Next
End Function